Game: BAGQUEST.BAS

vidak

not yet running.

targeting this:

this is the code as it stands:

0 REM BAGQUEST
9 REM CONSTANTS
10 REM
   
99 REM INITIALISATION
100 CLS
110 REM SET BG COLOUR
120 REM SET FG COLOUR
130 DIM W(40,10):REM WORLD ARRAY
140 DIM B(10):REM BAG PARENT CONNECTION
150 DIM BX(10):REM BAG ENTRY POSITIONS
160 DIM BY(10):REM BAG EXIT POSITIONS
170 CURRENTBAG = 1:REM START IN BAG 1 (MAIN WORLD)
180 P = INT(RND(1)*40)+1:REM PLAYER POSITION ON INIT
190 HAVEBAG=10:REM START WITH 10 BAGS (??)
    
499 REM INITIALISE BAGS
500 FOR BAG=1 TO 10
510     FOR POSITION=1 TO 40
520         W(POSITION,BAG)=0
530     NEXT POSITION
540     B(BAG)=0
550     BX(BAG)=0
560     BY(BAG)=0
570 NEXT BAG
580 W(P,1)=1:REM INITIALISE BAG 1
     
    REM 1 = PLAYER
    REM 2 = PLACED BAG
    REM 3 = BAG EXIT
    
999 REM DRAW CURRENT BAG
1000 REM CLS
1010 PRINT "BAGQUEST - BAG: ";CURRENTBAG;"."
1020 PRINT "=~=~=~=~========================~=~=~=~="
1030 FOR POSITION=1 TO 40
1040     IF POSITION=P THEN PRINT "@";:GOTO
1050     IF W(POSITION,CURRENTBAG)=0 THEN PRINT ".";:GOTO 1500
1060     IF W(POSITION,CURRENTBAG)=2 THEN PRINT "B";:GOTO 1500
1070     IF W(POSITION,CURRENTBAG)=3 THEN PRINT "X";:GOTO 1500
1500 NEXT POSITION
1510 PRINT
1520 PRINT "=~=~=~=~========================~=~=~=~="
1530 PRINT
     
1999 REM STATUS DISPLAY
2000 PRINT "YOU HAVE ";HAVEBAG;" BAG(S)."
2010 PRINT "YOU HAVE FOUND ";BAGSFOUND;" BAG-WORLDS."
2020 PRINT "POSITION: ";P
2030 PRINT
2040 PRINT "=~=~=~=~========================~=~=~=~="
2050 IF CURRENTBAG > 1 THEN PRINT "FIND EXIT (X) TO RETURN."
2060 PRINT "CONTROLS: A/D=MOVE. I=INFO. Q=QUIT."

2999 REM INPUT
3000 GET A$:IF A$="" THEN 3000
3010 OP=P
3020 IF A$="A" AND P>1 THEN W(P,CURRENTBAG)=0:P=P-1:GOSUB 4000:GOTO 1000
3030 IF A$="D" AND P<40 THEN W(P,CURRENTBAG)=0:P=P+1:GOSUB 4000:GOTO 1000
3040 IF A$="I" THEN GOSUB 8000
3050 IF A$="B" THEN AND HAVEBAG>0 GOSUB 5000
3060 IF A$="X" THEN GOSUB 7000
3070 IF A$="Q" THEN PRINT "GAME OVER":END
3080 GOTO 1000
       
3999 REM COLLISIONS
4000 IF W(P,CURRENTBAG)=0 THEN W(P,CURRENTBAG)=1:RETURN
4000 IF W(P,CURRENTBAG)=3 THEN GOSUB 6000
4010 RETURN
     
4999 REM PLACE A BAG
5000 IF W(P,CURRENTBAG)<>0 THEN PRINT "CANNOT PLACE BAG HERE.":RETURN
5010 IF HAVEBAG<=0 THEN PRINT "YOU HAVE NO BAGS.":RETURN
5020 FOR NEWBAG=1 TO 10
5030     IF NEWBAG=CURRENTBAG THEN GOTO 5050
5040     IF B(NEWBAG)=0 THEN GOTO 5080
5050 NEXT NEWBAG
5060 REM FALL INTO HERE
5070 PRINT "TOO MANY BAGS ALREADY.":RETURN
5080 REM RECORD WHERE THIS BAG LEADS
5090 B(NEWBAG)=CURRENTBAG
5100 BX(NEWBAG)=P
5110 BY(NEWBAG)=CURRENTBAG
5120 REM CREATE NEW EMPTY BAG
5130 FOR I=1 TO 40:W(I,NEWBAG)=0:NEXT I
5140 REM PLACE EXIT IN NEW BAG
5150 BAGEXIT=INT(RND(1)*40)+1
5160 W(BAGEXIT,NEWBAG)=3
5170 REM PLACE ENTRY IN CURRENT BAG
5180 W(P,CURRENTBAG)=2
5190 HAVEBAG=HAVEBAG-1
5200 BAGSFOUND=BAGSFOUND+1
5210 PRINT "BAG PLACED. STEP ON B TO ENTER NEW BAG."
5220 RETURN
     
5999 REM ENTER PLACED BAG
6000 FOR NEWBAG=1 TO 10
	 IF NEWBAG=CURRENTBAG THEN GOTO
	 IF BX(NEWBAG)=P AND BY(NEWBAG)=CURRENTBAG THEN GOTO
     NEXT NEWBAG
     PRINT "ERROR: BROKEN BAG LINK.":RETURN
     REM SWITCH TO THE NEW BAG
     W(P,CURRENTBAG)=0
     CURRENTBAG=NEWBAG
     P=INT(RND(1)*40)+1
     REM FIND EMPTY SPOT IN EXISTING BAG
     FOR TRY=1 TO 100
	 IF W(P,CURRENTBAG)=0 THEN GOTO
	 P=INT(RND(1)*40)+1
     NEXT TRY
     W(P,CURRENTBAG)=1
     PRINT "YOU ENTER A NEW BAG..."
     RETURN
     
6999 REM USE BAG EXIT
7000 
     
7999 REM INFO SCREEN
8000

vidak

Discussion thread on the fediverse here:

https://anticapitalist.party/@dirtycommo/116668880212664485

vidak

we’re getting very close to having item generation finished.


changed the colour scheme a bit too.

0 rem bagquest
9 rem constants
10 white = 5
11 red = 28
12 yellow = 158
13 blue = 154
14 green = 30
15 lightred = 150
16 purple = 156
17 dark = 151
19 brown = 129
   
   rem 0 - black
   rem 1 - white
   rem 2 - red
   rem 3 - cyan
   rem 4 - purple
   rem 5 - green
   rem 6 - blue
   rem 7 - yellow
   rem 8 - orange
   rem 9 - brown
   rem 10 - light red
   rem 11 - dark grey
   rem 12 - grey
   rem 13 - light green
   rem 14 - light blue
   rem 15 - light grey

99 rem initialisation
100 print chr$(147)
110 poke 53280,7:rem set border yellow
120 poke 53281,14:rem set bg light blue
130 dim w(40,10):rem world array
140 dim b(10):rem bag parent connection
150 dim bx(10):rem bag entry positions
160 dim by(10):rem bag exit positions
170 cb = 1:rem start in bag 1 (main world)
180 p = int(rnd(1)*40)+1:rem player position on init
190 hb=10:rem start with 10 bags (??)
200 bf=1
    
499 rem initialise bags
500 for i=1 to 10
510     for j=1 to 40
520         w(j,i)=0
530     next j
540     b(i)=0
550     bx(i)=0
560     by(i)=0
570 next i
580 w(p,1)=1:rem place player in bag 1
590 rem add items to bags, 10 items each
600 for i=1 to 10:rem 10 bags
610     for j=1 to 10:rem 10 items
620         q=int(rnd(1)*40)+1
630         if w(q,i)=0 then w(q,i)=int(rnd(1)*6)+4:goto 650
640         goto 620
650     next j
660 next i
    
    rem 0 = . empty space
    rem 1 = @ player
    rem 2 = B placed bag
    rem 3 = X bag exit
    rem 4 = L loot
    rem 5 = K key
    rem 6 = G goblin
    rem 7 = D door
    rem 8 = W magic wand
    rem 9 = M treasure map
    
999 rem draw current bag
1000 rem cls
1010 print tab(10);chr$(yellow);"*** bagquest ***":print
1015 print tab(20);chr$(white);" -> bag: ";cb;"."
1020 print chr$(yellow);"=-=-=-=-========================-=-=-=-="
1030 for i=1 to 40
1040     if w(i,cb)=0 then print chr$(dark);".";:goto 1500
1050     if w(i,cb)=1 then print chr$(white);"@";:goto 1500
1060     if w(i,cb)=2 then print chr$(blue);"b";:goto 1500
1070     if w(i,cb)=3 then print chr$(purple);"x";:goto 1500
1080     if w(i,cb)=4 then print chr$(yellow);"l";:goto 1500
1090     if w(i,cb)=5 then print chr$(red);"k";:goto 1500
1100     if w(i,cb)=6 then print chr$(green);"g";:goto 1500
1110     if w(i,cb)=7 then print chr$(brown);"d";:goto 1500
1120     if w(i,cb)=8 then print chr$(red);"w";:goto 1500
1130     if w(i,cb)=9 then print chr$(brown);"m";:goto 1500
1500 next i
1510 print
1520 print chr$(yellow);"=-=-=-=-========================-=-=-=-="
     
1999 rem status display
2000 print chr$(white);"you have ";hb;" bag(s)."
2010 print chr$(white);"you have found ";bf;" bag-worlds."
2020 print chr$(white);"position: ";p
2030 print
2040 print chr$(yellow);"=-=-=-=-========================-=-=-=-="
2050 if cb > 1 then print chr$(white);"find exit (x) to return."
2060 print chr$(white);"controls: a/d=move. i=info. q=quit."

2999 rem input
3000 get a$:if a$="" then 3000
3010 op=p
3020 if a$="a" and p>1 then w(p,cb)=0:p=p-1:gosub 4000:goto 1000
3030 if a$="d" and p<40 then w(p,cb)=0:p=p+1:gosub 4000:goto 1000
3040 if a$="i" then gosub 8000
3050 if a$="b" then and hb>0 gosub 5000
3060 if a$="x" then gosub 7000
3070 if a$="q" then print "game over":end
3080 goto 1000
       
3999 rem collisions
4000 if w(p,cb)=0 then w(p,cb)=1:return
4010 if w(p,cb)=2 then gosub 6000:return
4020 if w(p,cb)=3 then gosub 7000:return
4030 if w(p,cb)=4 then l=l+1:w(p,cb)=1:return
4040 if w(p,cb)=5 then k=k+1:w(p,cb)=1:return
4050 if w(p,cb)=6 then print chr$(green);"a goblin!":gosub 9100:return
4060 if w(p,cb)=7 then gosub 9200:return
4070 if w(p,cb)=8 then mw=mw+1:w(p,cb)=1:print chr$(red);"wand!":gosub 9000:return
4080 if w(p,cb)=9 then m=m+1:w(p,cb)=1:print chr$(brown);"map!":gosub 9000:return
4090 return
     
4999 rem place a bag
5000 if w(p,cb)<>0 then print "cannot place bag here.":return
5010 if hb<=0 then print "you have no bags.":return
5020 for newbag=1 to 10
5030     if newbag=cb then goto 5050
5040     if b(newbag)=0 then goto 5080
5050 next newbag
5060 rem fall into here
5070 print "too many bags already.":return
5080 rem record where this bag leads
5090 b(newbag)=cb
5100 bx(newbag)=p
5110 by(newbag)=cb
5120 rem create new empty bag
5130 for i=1 to 40:w(i,newbag)=0:next i
5140 rem place exit in new bag
5150 bagexit=int(rnd(1)*40)+1
5160 w(bagexit,newbag)=3
5170 rem place entry in current bag
5180 w(p,cb)=2
5190 hb=hb-1
5200 bf=bf+1
5210 print "bag placed. step on b to enter new bag."
5220 return
     
5999 rem enter placed bag
6000 for newbag=1 to 10
	 if newbag=cb then goto
	 if bx(newbag)=p and by(newbag)=cb then goto
     next newbag
     print "error: broken bag link.":return
     rem switch to the new bag
     w(p,cb)=0
     cb=newbag
     p=int(rnd(1)*40)+1
     rem find empty spot in existing bag
     for try=1 to 100
	 if w(p,cb)=0 then goto
	 p=int(rnd(1)*40)+1
     next try
     w(p,cb)=1
     print "you enter a new bag..."
     return
     
6999 rem use bag exit
7000 
     
7999 rem info screen
8000

vidak

starting to come together. i have decided to include echo symbols inside the world generation sequence.

vice-video-2026060907270291.mp4

774kB

vidak

the game is taking shape.

pretty much every game mechanic works now, but i still need to fix a few things.

if you copy and paste this into a Commodore 64 emulator, it should work.

0 rem bagquest
5 rem constants
9 rem character colour codes
10 white = 5
11 red = 28
12 yellow = 158
13 blue = 154
14 green = 30
15 lightred = 150
16 purple = 156
17 dark = 151
19 brown = 129
   

   rem border and bg colour codes
   rem
   rem 0 - black
   rem 1 - white
   rem 2 - red
   rem 3 - cyan
   rem 4 - purple
   rem 5 - green
   rem 6 - blue
   rem 7 - yellow
   rem 8 - orange
   rem 9 - brown
   rem 10 - light red
   rem 11 - dark grey
   rem 12 - grey
   rem 13 - light green
   rem 14 - light blue
   rem 15 - light grey

99 rem initialisation
100 print chr$(147)
110 poke 53280,7:rem set border yellow
120 poke 53281,14:rem set bg light blue
130 dim w(40,10):rem world array
140 dim b(10):rem bag parent connection
150 dim bx(10):rem bag entry positions
160 dim by(10):rem bag exit positions
170 cb = 1:rem start in bag 1 (main world)
180 p = int(rnd(1)*40)+1:rem player position on init
190 hb=10:rem start with 10 bags (??)
200 bf=1
210 l=0:rem loot
220 k=0:rem keys
230 mw=0:rem magic wands
240 m=0:rem treasure maps
    

499 rem initialise bags
500 print chr$(white);"initialising bags..."
510 for i=1 to 10
520     for j=1 to 40
530         w(j,i)=0
540     next j
550     b(i)=0
560     bx(i)=0
570     by(i)=0
580 next i
590 print "bags initialised - ok.":gosub 9000
600 w(p,1)=1:rem place player in bag 1
610 rem add items to bags, 10 items each
620 print "generating item positions..."
625 print "generating bag..."
630 for i=1 to 10:rem 10 bags
635     print tab(10);i
640     for j=1 to 10:rem 10 items
650         q=int(rnd(1)*40)+1
660         if w(q,i)=0 then w(q,i)=int(rnd(1)*6)+4:goto 680
670         goto 650
680     next j
690 next i
700 print "world initialised - ok.":gosub 9000
    

    rem 0 = . empty space
    rem 1 = @ player
    rem 2 = B placed bag
    rem 3 = X bag exit
    rem 4 = L loot
    rem 5 = K key
    rem 6 = G goblin
    rem 7 = D door
    rem 8 = W magic wand
    rem 9 = M treasure map
    

999 rem draw current bag
1000 print chr$(147)
1010 print tab(10);chr$(yellow);"*** bagquest ***":print
1015 print chr$(white);"b:";hb;" bf:";bf;" l:";l;" k:";k;" wd:";mw;" m:";m
1017 print chr$(white);"current bag:";cb;" @:";p
1020 print chr$(yellow);"--------========================--------"
1030 for i=1 to 40
1040     if w(i,cb)=0 then print chr$(dark);".";:goto 1500
1050     if w(i,cb)=1 then print chr$(white);"@";:goto 1500
1060     if w(i,cb)=2 then print chr$(lightred);"b";:goto 1500
1070     if w(i,cb)=3 then print chr$(purple);"x";:goto 1500
1080     if w(i,cb)=4 then print chr$(yellow);"l";:goto 1500
1090     if w(i,cb)=5 then print chr$(red);"k";:goto 1500
1100     if w(i,cb)=6 then print chr$(green);"g";:goto 1500
1110     if w(i,cb)=7 then print chr$(brown);"d";:goto 1500
1120     if w(i,cb)=8 then print chr$(red);"w";:goto 1500
1130     if w(i,cb)=9 then print chr$(brown);"m";:goto 1500
1500 next i
1510 print
     

1999 rem status display
2000 print chr$(yellow);"--------========================--------"
2010 print chr$(white);"a/d=move. b=place bag. x=use exit."
2020 print chr$(white);"w=wand. m=map. i=info. q=quit."
2030 rem see line 1017
2040 print
2050 print chr$(yellow);"--------========================--------"
2060 if cb > 1 then print chr$(white);"find exit (x) to return."

2999 rem input
3000 get a$:if a$="" then 3000
3010 op=p
3020 if a$="a" and p>1 then w(p,cb)=0:p=p-1:gosub 4000:goto 1000
3030 if a$="d" and p<40 then w(p,cb)=0:p=p+1:gosub 4000:goto 1000
3040 if a$="i" then gosub 8000
3050 if a$="b" and hb>0 then gosub 5000
3060 rem if a$="x" then gosub 7000
3070 if a$="q" then print "game over":end
3080 if a$="w" and mw>0 then gosub 10000
3090 if a$="m" and m>0 then gosub 11000
3100 goto 1000
       

3999 rem collisions
4000 if w(p,cb)=0 then w(p,cb)=1:return
4010 if w(p,cb)=2 then gosub 6000:return
4020 if w(p,cb)=3 then gosub 7000:return
4030 if w(p,cb)=4 then l=l+1:w(p,cb)=1:return
4040 if w(p,cb)=5 then k=k+1:w(p,cb)=1:return
4050 if w(p,cb)=6 then print chr$(green);"a goblin!":gosub 9100:return
4060 if w(p,cb)=7 then gosub 9200:return
4070 if w(p,cb)=8 then mw=mw+1:w(p,cb)=1:print "wand!":gosub 9000:return
4080 if w(p,cb)=9 then m=m+1:w(p,cb)=1:print "map!":gosub 9000:return
4090 return
     

4999 rem place a bag
5000 tp=0:if hb<=0 then print "you have no bags.":gosub 9000:return
5010 rem check left and right for empty space
5020 if p>1 and w(p-1,cb)=0 then tp=p-1:goto 5050
5030 if p<40 and w(p+1,cb)=0 then tp=p+1:goto 5050
5040 print "no empty space adjacent.":gosub 9000:return
5050 rem find empty bag slot     

5060 for i=2 to 10
5070     if i=cb then goto 5090
5080     if b(i)=0 then goto 5120
5090 next i
5100 rem fall into here
5110 print "too many bags already.":return
5120 rem record where this bag leads
5130 b(i)=cb
5132 print "placed bag i=";i;" parent=";cb;" entry";tp
5133 gosub 9000
5140 bx(i)=tp
5150 by(i)=cb
5160 rem place exit in new bag
5170 be=int(rnd(1)*40)+1
5180 if w(be,i)<>0 then goto 5170:rem this could be an infinite loop uwu
5190 rem this line blank intentionally
5200 w(be,i)=3
5210 rem place entry in current bag
5220 w(tp,cb)=2
5230 hb=hb-1
5240 bf=bf+1
5250 print "bag placed at position";tp
5260 gosub 9000
5270 return
     

5999 rem enter placed bag
6000 for i=1 to 10
6010     if i=cb then goto 6030
6020     if bx(i)=p and by(i)=cb then goto 6050
6030 next i
6040 print "error: broken bag link.":return
6050 rem switch to the new bag
6060 w(p,cb)=0
6070 cb=i
6080 rem find empty spot in existing bag
6090 p=int(rnd(1)*40)+1
6100 if w(p,cb)<>0 then goto 6090
6110 w(p,cb)=1
6120 print "you enter a new bag..."
6130 gosub 9000
6140 return
     

6999 rem use bag exit
7000 rem if w(p,cb)<>3 then print "not an exit...":gosub 9000:return
7001 print "exit debug: cb=";cb
7002 for t=1 to 10:print "b(";t;")=";b(t):next t:print:gosub 9000
7010 if cb=1 then print "cannot leave main world...":gosub 9000:return
7015 print "b(";cb;")=";b(cb):gosub 9000
7020 pr=b(cb)
7025 print "pr=";pr:gosub 9000
7030 if pr=0 then print "error: no parent world.":gosub 9000:return
7040 w(p,cb)=0
7050 p=bx(cb)
7060 cb=pr
7070 w(p,cb)=1
7080 print "you return through the exit..."
7090 gosub 9000
7100 return
     

7999 rem info screen
8000 print chr$(147)
8010 print tab(10);chr$(yellow);"=== bagquest ==="
8020 print
8030 print chr$(white);"you have";hb;" bags."
8040 print "bags visited:";bf
8050 print "current bag:";cb
8060 print "current position:";p
8070 print
8080 print chr$(yellow);"loot:";l
8090 print "keys:";k
8100 print "wands:";mw
8110 print "treasure maps:";m
8120 print
8130 print chr$(white);
8140 gosub 9000
8150 return
     

     

8999 rem delay
9000 for t=1 to 1000:next t
9010 return
     

9099 rem bribing the goblins
9100 if l>0 then l=l-1:print "goblin bribed.":gosub 9000:w(p,cb)=1:return
9110 print "goblin requires bribe!"
9120 p=op
9130 gosub 9000
9140 return
     

9199 rem doors need keys
9200 if k>0 then k=k-1:print "door unlocked.":gosub 9000:return
9210 print "door needs a key...":gosub 9000:p=op:w(p,cb)=1:return
     

9999 rem magic wand
10000 tb=int(rnd(1)*10)+1
10010 if tb=cb then goto 10000
10020 tp=int(rnd(1)*40)+1
10030 if w(tp,tb)<>0 then goto 10020
10040 w(p,cb)=0
10050 cb=tb
10060 p=tp
10070 w(p,cb)=1
10080 mw=mw-1
10090 print "wand teleports you to bag";cb;"at position";p
10100 gosub 9000
10110 return
      

10999 rem treasure map
11000 print "which bag? (1-10, 0=cancel)"
11010 input tb
11020 if tb=0 then print "map folded.":gosub 9000:return
11030 if tb<1 or tb>10 then print "invalid selection.":gosub 9000:return
11040 if tb=cb then print "already in bag...":gosub 9000:return
11050 w(p,cb)=0
11060 cb=tb
11070 tp=int(rnd(1)*40)+1
11080 if w(tp,cb)<>0 then goto 11070
11090 p=tp
11100 w(p,cb)=1
11110 print "map takes you to bag";cb;"at position";p
11120 gosub 9000
11130 return
```

vidak

please find attached the latest version of the code.

i have made it so that bag entries (B) and exits (X) will not be erased upon use. now, placing a bag will make entries and exits are permanent each play through.

currently the game is about 8 KB, and comes in at about ₂₅₀ lines.

ideas:

record game play events and allow an ‘infinite’ undo button, for the purpose of correcting mistakes
need to explore better colours
fix the draw speed problem (perhaps put the play field right at the bottom of the screen)
now that the core functionality of the game is working properly, something inside me thinks I should add more items, or at least tinker with the keys/doors, loot/goblins pairing, which i feel could be more creative
a 2D play field seems possible

0 rem bagquest
1 rem public domain licence
5 rem constants
9 rem character colour codes
10 white = 5
11 red = 28
12 yellow = 158
13 blue = 154
14 green = 30
15 lightred = 150
16 purple = 156
17 dark = 151
19 brown = 129
   
   rem border and bg colour codes
   rem
   rem 0 - black
   rem 1 - white
   rem 2 - red
   rem 3 - cyan
   rem 4 - purple
   rem 5 - green
   rem 6 - blue
   rem 7 - yellow
   rem 8 - orange
   rem 9 - brown
   rem 10 - light red
   rem 11 - dark grey
   rem 12 - grey
   rem 13 - light green
   rem 14 - light blue
   rem 15 - light grey

99 rem initialisation
100 print chr$(147)
110 poke 53280,7:rem set border yellow
120 poke 53281,14:rem set bg light blue
130 dim w(40,10):rem world array
140 dim b(10):rem bag parent connection
150 dim bx(10):rem bag entry positions
160 dim by(10):rem bag exit positions
170 cb = 1:rem start in bag 1 (main world)
180 p = int(rnd(1)*40)+1:rem player position on init
190 hb=10:rem start with 10 bags (??)
200 bf=1
210 l=0:rem loot
220 k=0:rem keys
230 mw=0:rem magic wands
240 m=0:rem treasure maps
    
499 rem initialise bags
500 print chr$(white);"initialising bags..."
510 for i=1 to 10
520     for j=1 to 40
530         w(j,i)=0
540     next j
550     b(i)=0
560     bx(i)=0
570     by(i)=0
580 next i
590 print "bags initialised - ok.":gosub 9000
600 w(p,1)=1:rem place player in bag 1
610 rem add items to bags, 10 items each
620 print "generating item positions..."
625 print "generating bag..."
630 for i=1 to 10:rem 10 bags
635     print tab(10);i
640     for j=1 to 10:rem 10 items
650         q=int(rnd(1)*40)+1
660         if w(q,i)=0 then w(q,i)=int(rnd(1)*6)+4:goto 680
670         goto 650
680     next j
690 next i
700 print "world initialised - ok.":gosub 9000
    
    rem 0 = . empty space
    rem 1 = @ player
    rem 2 = B placed bag
    rem 3 = X bag exit
    rem 4 = L loot
    rem 5 = K key
    rem 6 = G goblin
    rem 7 = D door
    rem 8 = W magic wand
    rem 9 = M treasure map
    
999 rem draw current bag
1000 print chr$(147)
1010 print tab(10);chr$(yellow);"*** bagquest ***":print
1015 print chr$(white);"b:";hb;" bf:";bf;" l:";l;" k:";k;" wd:";mw;" m:";m
1017 print chr$(white);"current bag:";cb;" @:";p
1020 print chr$(yellow);"--------========================--------"
1030 for i=1 to 40
1040     if w(i,cb)=0 then print chr$(dark);".";:goto 1500
1050     if w(i,cb)=1 then print chr$(white);"@";:goto 1500
1060     if w(i,cb)=2 then print chr$(lightred);"b";:goto 1500
1070     if w(i,cb)=3 then print chr$(purple);"x";:goto 1500
1080     if w(i,cb)=4 then print chr$(yellow);"l";:goto 1500
1090     if w(i,cb)=5 then print chr$(red);"k";:goto 1500
1100     if w(i,cb)=6 then print chr$(green);"g";:goto 1500
1110     if w(i,cb)=7 then print chr$(brown);"d";:goto 1500
1120     if w(i,cb)=8 then print chr$(red);"w";:goto 1500
1130     if w(i,cb)=9 then print chr$(brown);"m";:goto 1500
1500 next i
1510 print
     
1999 rem status display
2000 print chr$(yellow);"--------========================--------"
2010 print chr$(white);"a/d=move. b=place bag. x=use exit."
2020 print chr$(white);"w=wand. m=map. i=info. q=quit."
2030 rem see line 1017
2040 print
2050 print chr$(yellow);"--------========================--------"
2060 if cb > 1 then print chr$(white);"find exit (x) to return."

2999 rem input
3000 get a$:if a$="" then 3000
3010 if a$="a" and p>1 then op=p:p=p-1:gosub 3500:gosub 4000:goto 1000
3020 if a$="d" and p<40 then op=p:p=p+1:gosub 3500:gosub 4000:goto 1000
3030 if a$="i" then gosub 8000
3040 if a$="b" and hb>0 then gosub 5000
3050 rem if a$="x" then gosub 7000
3060 if a$="q" then print "game over":end
3070 if a$="w" and mw>0 then gosub 10000
3080 if a$="m" and m>0 then gosub 11000
3090 goto 1000
     
3499 rem move player such that bag entry and exits not erased
3500 if w(op,cb)<>2 and w(op,cb)<>3 then w(op,cb)=0
3510 if w(p,cb)=0 then w(p,cb)=1
3520 return
       
3999 rem collisions
4000 if w(p,cb)=0 then w(p,cb)=1:return
4010 if w(p,cb)=2 then gosub 6000:return
4020 if w(p,cb)=3 then gosub 7000:return
4030 if w(p,cb)=4 then l=l+1:w(p,cb)=1:return
4040 if w(p,cb)=5 then k=k+1:w(p,cb)=1:return
4050 if w(p,cb)=6 then print chr$(green);"a goblin!":gosub 9100:return
4060 if w(p,cb)=7 then gosub 9200:return
4070 if w(p,cb)=8 then mw=mw+1:w(p,cb)=1:print "wand!":gosub 9000:return
4080 if w(p,cb)=9 then m=m+1:w(p,cb)=1:print "map!":gosub 9000:return
4090 return
     
4999 rem place a bag
5000 tp=0:if hb<=0 then print "you have no bags.":gosub 9000:return
5010 rem check left and right for empty space
5020 if p>1 and w(p-1,cb)=0 then tp=p-1:goto 5050
5030 if p<40 and w(p+1,cb)=0 then tp=p+1:goto 5050
5040 print "no empty space adjacent.":gosub 9000:return
5050 rem find empty bag slot     
5060 for i=2 to 10
5070     if i=cb then goto 5090
5080     if b(i)=0 then goto 5120
5090 next i
5100 rem fall into here
5110 print "too many bags already.":return
5120 rem record where this bag leads
5130 b(i)=cb
5132 print "placed bag i=";i;" parent=";cb;" entry";tp
5133 gosub 9000
5140 bx(i)=tp
5150 by(i)=cb
5160 rem place exit in new bag
5170 be=int(rnd(1)*40)+1
5180 if w(be,i)<>0 then goto 5170:rem this could be an infinite loop uwu
5190 rem this line blank intentionally
5200 w(be,i)=3
5210 rem place entry in current bag
5220 w(tp,cb)=2
5230 hb=hb-1
5240 bf=bf+1
5250 print "bag placed at position";tp
5260 gosub 9000
5270 return
     
5999 rem enter placed bag
6000 for i=1 to 10
6010     if i=cb then goto 6030
6020     if bx(i)=p and by(i)=cb then goto 6050
6030 next i
6040 print "error: broken bag link.":return
6050 rem switch to the new bag
6060 rem w(p,cb)=0
6070 cb=i
6080 rem find empty spot in existing bag
6090 p=int(rnd(1)*40)+1
6100 if w(p,cb)<>0 then goto 6090
6110 w(p,cb)=1
6120 print "you enter a new bag..."
6130 gosub 9000
6140 return
     
6999 rem use bag exit
7000 if cb=1 then print "cannot leave main world...":gosub 9000:return
7010 pr=b(cb)
7020 if pr=0 then print "error: no parent world.":gosub 9000:return
7030 rem ep (entry point)
7040 ep=bx(cb)
7050 rem find empty space next to bag entry
7060 if ep>1 and w(ep-1,pr)=0 then tp=ep-1:goto 7100
7070 if ep<40 and w(ep+1,pr)=0 then tp=ep+1:goto 7100
7080 rem fallback: place player directly on entry (both sides blocked)
7090 tp=ep
7100 rem w(p,cb)=0 preserve exit tile
7110 p=tp
7120 cb=pr
7130 w(p,cb)=1
7140 print "you return through the exit..."
7150 gosub 9000
7160 return
     
7999 rem info screen
8000 print chr$(147)
8010 print tab(10);chr$(yellow);"=== bagquest ==="
8020 print
8030 print chr$(white);"you have";hb;" bags."
8040 print "bags visited:";bf
8050 print "current bag:";cb
8060 print "current position:";p
8070 print
8080 print chr$(yellow);"loot:";l
8090 print "keys:";k
8100 print "wands:";mw
8110 print "treasure maps:";m
8120 print
8130 print chr$(white);
8140 gosub 9000
8150 return
     
     
8999 rem delay
9000 for t=1 to 1000:next t
9010 return
     
9099 rem bribing the goblins
9100 if l>0 then l=l-1:print "goblin bribed.":gosub 9000:w(p,cb)=1:return
9110 print "goblin requires bribe!"
9120 p=op
9130 gosub 9000
9140 return
     
9199 rem doors need keys
9200 if k>0 then k=k-1:print "door unlocked.":gosub 9000:return
9210 print "door needs a key...":gosub 9000:p=op:w(p,cb)=1:return
     
9999 rem magic wand
10000 tb=int(rnd(1)*10)+1
10010 if tb=cb then goto 10000
10020 tp=int(rnd(1)*40)+1
10030 if w(tp,tb)<>0 then goto 10020
10040 rem w(p,cb)=0
10050 cb=tb
10060 p=tp
10070 w(p,cb)=1
10080 mw=mw-1
10090 print "wand teleports you to bag";cb;"at position";p
10100 gosub 9000
10110 return
      
10999 rem treasure map
11000 print "which bag? (1-10, 0=cancel)"
11010 input tb
11020 if tb=0 then print "map folded.":gosub 9000:return
11030 if tb<1 or tb>10 then print "invalid selection.":gosub 9000:return
11040 if tb=cb then print "already in bag...":gosub 9000:return
11050 w(p,cb)=0
11060 cb=tb
11070 tp=int(rnd(1)*40)+1
11080 if w(tp,cb)<>0 then goto 11070
11090 p=tp
11100 w(p,cb)=1
11110 print "map takes you to bag";cb;"at position";p
11120 gosub 9000
11130 return